From b88d77fb2d0d5028a6f5670695dee6bec129501f Mon Sep 17 00:00:00 2001
From: Ryan Schanzenbacher <ryan@rschanz.org>
Date: Fri, 5 Apr 2024 11:57:45 -0400
Subject: ahhh sloppy fish, still needs fixing, esp with the vars

---
 home-config/fish/conf.d/_tide_init.fish | 44 +++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 home-config/fish/conf.d/_tide_init.fish

(limited to 'home-config/fish/conf.d/_tide_init.fish')

diff --git a/home-config/fish/conf.d/_tide_init.fish b/home-config/fish/conf.d/_tide_init.fish
new file mode 100644
index 0000000..b448002
--- /dev/null
+++ b/home-config/fish/conf.d/_tide_init.fish
@@ -0,0 +1,44 @@
+function _tide_init_install --on-event _tide_init_install
+    set -U VIRTUAL_ENV_DISABLE_PROMPT true
+
+    source (functions --details _tide_sub_configure)
+    _load_config lean
+    _tide_finish
+
+    if status is-interactive
+        tide bug-report --check || sleep 4
+
+        if contains ilancosman/tide (string lower $_fisher_plugins)
+            set_color bryellow
+            echo "ilancosman/tide is a development branch. Please install from a release tag:"
+            _tide_fish_colorize "fisher install ilancosman/tide@v6"
+            sleep 3
+        end
+
+        switch (read --prompt-str="Configure tide prompt? [Y/n] " | string lower)
+            case y ye yes ''
+                tide configure
+            case '*'
+                echo -s \n 'Run ' (_tide_fish_colorize "tide configure") ' to customize your prompt.'
+        end
+    end
+end
+
+function _tide_init_update --on-event _tide_init_update
+    # Warn users who install from main branch
+    if contains ilancosman/tide (string lower $_fisher_plugins)
+        set_color bryellow
+        echo "ilancosman/tide is a development branch. Please install from a release tag:"
+        _tide_fish_colorize "fisher install ilancosman/tide@v6"
+        sleep 3
+    end
+
+    # Set (disable) the new jobs variable
+    set -q tide_jobs_number_threshold || set -U tide_jobs_number_threshold 1000
+end
+
+function _tide_init_uninstall --on-event _tide_init_uninstall
+    set -e VIRTUAL_ENV_DISABLE_PROMPT
+    set -e (set -U --names | string match --entire -r '^_?tide')
+    functions --erase (functions --all | string match --entire -r '^_?tide')
+end
-- 
cgit v1.2.3