{ config, pkgs, lib, ... }:

{
  imports = [
    ./modules/sketchybar
    ./modules/simple-bar
    ./modules/taskwarrior-ubersicht
    ./modules/ubersicht
  ];

  ryan.sketchybar.enable = true;

  programs.zen-browser = {
    package = null; # managed via homebrew
    darwinDefaultsId = "app.zen-browser.zen";
  };

  # Need special config for gpg-agent on macOS
  home.file.".gnupg/gpg-agent.conf".text = ''
    pinentry-program ${pkgs.pinentry_mac}/Applications/pinentry-mac.app/Contents/MacOS/pinentry-mac
    enable-ssh-support
  '';

  # Add hammerspoon
  home.file.".hammerspoon".source = ./hammerspoon;

  home.file.".config/homebrew".source = config.lib.file.mkOutOfStoreSymlink "${config.home.homeDirectory}/.homebrew";

  home.packages = with pkgs; [
    iina # Media player (frontend to mpv essentially)
    jujutsu
    netbird-tui
  ];

  # Install User apps to subdir for dock stuff
  targets.darwin.linkApps.directory = "Applications/User Apps";

  # Symlink System apps into the user apps "system" dir
  home.activation.linkSystemApps = lib.hm.dag.entryAfter ["writeBoundary"] ''
    if [[ -z "$HOME" ]]; then
      echo "ERROR: HOME was not defined. This should not happen. Bailing! ">&2
      exit 1
    fi

    $DRY_RUN_CMD mkdir -p "$HOME/Applications/System Apps"

    $DRY_RUN_CMD rm -rf "$HOME/Applications/System Apps/"*.app

    $DRY_RUN_CMD find /Applications /System/Applications -maxdepth 2 -name "*.app" \
      -prune -exec ln -sf {} "$HOME/Applications/System Apps/" \;
  '';

  # Restart gpg-agent
  home.activation.restartGpgAgent = lib.hm.dag.entryAfter ["writeBoundary"] ''
    $DRY_RUN_CMD ${pkgs.gnupg}/bin/gpgconf --kill gpg-agent || true
  '';
}