guix/gnu/bootloader.scm

;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2017 David Craven <david@craven.ch>
;;; Copyright © 2017, 2020, 2022 Mathieu Othacehe <othacehe@gnu.org>
;;; Copyright © 2017 Leo Famulari <leo@famulari.name>
;;; Copyright © 2019, 2021, 2023 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2020 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
;;; Copyright © 2022 Josselin Poiret <dev@jpoiret.xyz>
;;; Copyright © 2022 Reza Alizadeh Majd <r.majd@pantherx.org>
;;; Copyright © 2024 Tomas Volf <~@wolfsden.cz>
;;; Copyright © 2024 Lilah Tascheter <lilah@lunabee.space>
;;; Copyright © 2024 Herman Rimm <herman@rimm.ee>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu bootloader)
  #:autoload   (gnu build file-systems)
               (read-partition-label read-partition-uuid
                find-partition-by-label find-partition-by-uuid)
  #:use-module (gnu services configuration)
  #:use-module (gnu system file-systems)
  #:use-module (gnu system uuid)
  #:autoload   (guix build syscalls)
               (mounts mount-source mount-point mount-type)
  #:use-module (guix deprecation)
  #:use-module (guix diagnostics)
  #:use-module (guix gexp)
  #:use-module (guix i18n)
  #:use-module (guix modules)
  #:use-module (guix profiles)
  #:use-module (guix records)
  #:use-module (guix utils)
  #:use-module (ice-9 match)
  #:use-module (ice-9 receive)
  #:use-module (ice-9 regex)
  #:use-module (rnrs bytevectors)
  #:use-module (srfi srfi-1)
  #:use-module (srfi srfi-26)
  #:use-module (srfi srfi-34)
  #:use-module (srfi srfi-35)
  #:export (menu-entry
            menu-entry?
            menu-entry-label
            menu-entry-device
            menu-entry-device-mount-point
            menu-entry-device-subvol
            menu-entry-linux
            menu-entry-linux-arguments
            menu-entry-initrd
            menu-entry-multiboot-kernel
            menu-entry-multiboot-arguments
            menu-entry-multiboot-modules
            menu-entry-chain-loader

            normalize-file
            menu-entry->sexp
            sexp->menu-entry

            bootloader
            bootloader?
            bootloader-name
            bootloader-default-targets
            bootloader-installer

            bootloader-target
            bootloader-target?
            bootloader-target-type
            bootloader-target-expected?
            bootloader-target-path
            bootloader-target-offset
            bootloader-target-device
            bootloader-target-file-system

            target-error?
            target-error-type
            target-error-targets

            find-mount
            find-file-system
            label->uuid
            uuid->file-system
            mount-point->block-device

            gbegin
            :path :devpath :device :fs :label :uuid
            with-targets

            bootloader-configuration
            bootloader-configuration?
            bootloader-configuration-bootloader
            bootloader-configuration-targets
            bootloader-configuration-menu-entries
            bootloader-configuration-default-entry
            bootloader-configuration-efi-removable?
            bootloader-configuration-32bit?
            bootloader-configuration-keypair
            bootloader-configuration-timeout
            bootloader-configuration-keyboard-layout
            bootloader-configuration-theme
            bootloader-configuration-terminal-outputs
            bootloader-configuration-terminal-inputs
            bootloader-configuration-serial-unit
            bootloader-configuration-serial-speed
            bootloader-configuration-device-tree-support?
            bootloader-configuration-extra-initrd

            bootloader-configuration->gexp
            bootloader-configurations->gexp

            match-bootloader-configuration
            match-menu-entry

            %efi-supported-systems
            efi-arch
            install-efi))


;;;
;;; Menu-entry record.
;;;

(define-record-type* <menu-entry>
  menu-entry make-menu-entry
  menu-entry?
  (label           menu-entry-label)
  (device          menu-entry-device       ; file system uuid, label, or #f
                   (default #f))
  (device-mount-point menu-entry-device-mount-point
                   (default #f))
  (device-subvol menu-entry-device-subvol
                   (default #f))
  (linux           menu-entry-linux
                   (default #f))
  (linux-arguments menu-entry-linux-arguments
                   (default '()))          ; list of string-valued gexps
  (initrd          menu-entry-initrd       ; file name of the initrd as a gexp
                   (default #f))
  (multiboot-kernel menu-entry-multiboot-kernel
                    (default #f))
  (multiboot-arguments menu-entry-multiboot-arguments
                       (default '()))      ; list of string-valued gexps
  (multiboot-modules menu-entry-multiboot-modules
                     (default '()))        ; list of multiboot commands, where
                                           ; a command is a list of <string>
  (chain-loader     menu-entry-chain-loader
                    (default #f)))         ; string, path of efi file

(define (normalize-file entry file)
  "Normalize a file FILE stored in a menu entry into one suitable for a
bootloader.  Realizes device-mount-point and device-subvol."
  (match-menu-entry entry (device-mount-point device-subvol)
    ;; Avoid using cut procedure from SRFI-26 inside G-exp.
    (let ((mount (and=> device-mount-point (cut string-trim <> #\/))))
      #~(let* ((file (string-trim #$file #\/))
               (file (if (and #$mount (string-prefix? #$mount file))
                         (substring file (string-length #$mount))
                         file)))
          (string-append (or #$device-subvol "") "/" file)))))

(define (report-menu-entry-error menu-entry)
  (raise
   (condition
    (&message
     (message
      (format #f (G_ "invalid menu-entry: ~a") menu-entry)))
    (&fix-hint
     (hint
      (G_ "Please chose only one of:
@enumerate
@item direct boot by specifying fields @code{linux},
@code{linux-arguments} and @code{linux-modules},
@item multiboot by specifying fields @code{multiboot-kernel},
@code{multiboot-arguments} and @code{multiboot-modules},
@item chain-loader by specifying field @code{chain-loader}.
@end enumerate"))))))

(define (menu-entry->sexp entry)
  "Return ENTRY serialized as an sexp."
  (define (device->sexp device)
    (match device
      ((? uuid? uuid)
       `(uuid ,(uuid->string uuid) ,(uuid-type uuid)))
      ((? file-system-label? label)
       `(label ,(file-system-label->string label)))
      (_ device)))
  (match entry
    (($ <menu-entry> label device mount-point subvol
                     (? identity linux) linux-arguments (? identity initrd)
                     #f () () #f)
     `(menu-entry (version 0)
                  (label ,label)
                  (device ,(device->sexp device))
                  (device-mount-point ,mount-point)
                  (linux ,linux)
                  (linux-arguments ,linux-arguments)
                  (initrd ,initrd)
                  (device-subvol ,subvol)))
    (($ <menu-entry> label device mount-point subvol #f () #f
                     (? identity multiboot-kernel) multiboot-arguments
                     multiboot-modules #f)
     `(menu-entry (version 0)
                  (label ,label)
                  (device ,(device->sexp device))
                  (device-mount-point ,mount-point)
                  (multiboot-kernel ,multiboot-kernel)
                  (multiboot-arguments ,multiboot-arguments)
                  (multiboot-modules ,multiboot-modules)
                  (device-subvol ,subvol)))
    (($ <menu-entry> label device mount-point subvol #f () #f #f () ()
                     (? identity chain-loader))
     `(menu-entry (version 0)
                  (label ,label)
                  (device ,(device->sexp device))
                  (device-mount-point ,mount-point)
                  (chain-loader ,chain-loader)
                  (device-subvol ,subvol)))
    (_ (report-menu-entry-error entry))))

(define (sexp->menu-entry sexp)
  "Turn SEXP, an sexp as returned by 'menu-entry->sexp', into a <menu-entry>
record."
  ;; XXX: The match ORs shadow subvol.
  (define subvol #f)
  (define (sexp->device device-sexp)
    (match device-sexp
      (('uuid uuid-string type)
       (uuid uuid-string type))
      (('label label)
       (file-system-label label))
      (_ device-sexp)))
  (match sexp
    (('menu-entry ('version 0)
                  ('label label) ('device device)
                  ('device-mount-point mount-point)
                  ('linux linux) ('linux-arguments linux-arguments)
                  ('initrd initrd)
                  (or ('device-subvol subvol _ ...) (_ ...)))
     (menu-entry
      (label label)
      (device (sexp->device device))
      (device-mount-point mount-point)
      (device-subvol subvol)
      (linux linux)
      (linux-arguments linux-arguments)
      (initrd initrd)))
    (('menu-entry ('version 0)
                  ('label label) ('device device)
                  ('device-mount-point mount-point) ('device-subvol subvol)
                  ('multiboot-kernel multiboot-kernel)
                  ('multiboot-arguments multiboot-arguments)
                  ('multiboot-modules multiboot-modules)
                  (or ('device-subvol subvol _ ...) (_ ...)))
     (menu-entry
      (label label)
      (device (sexp->device device))
      (device-mount-point mount-point)
      (device-subvol subvol)
      (multiboot-kernel multiboot-kernel)
      (multiboot-arguments multiboot-arguments)
      (multiboot-modules multiboot-modules)))
    (('menu-entry ('version 0)
                  ('label label) ('device device)
                  ('device-mount-point mount-point) ('device-subvol subvol)
                  ('chain-loader chain-loader)
                  (or ('device-subvol subvol _ ...) (_ ...)))
     (menu-entry
      (label label)
      (device (sexp->device device))
      (device-mount-point mount-point)
      (device-subvol subvol)
      (chain-loader chain-loader)))))


;;;
;;; Bootloader record.
;;;

;; The <bootloader> record contains fields expressing how the bootloader
;; should be installed. Every bootloader in gnu/bootloader/ directory
;; has to be described by this record.

(define-record-type* <bootloader>
  bootloader make-bootloader bootloader?
  (name            bootloader-name)
  (default-targets bootloader-default-targets (default '()))
  (installer       bootloader-installer))


;;;
;;; Bootloader target record.
;;;

;; <bootloader-target> represents different kinds of targets in a
;; normalized form.

(define (string-or-boolean? x)
  (or (string? x) (boolean? x)))

(define (symbol-or-boolean? x)
  (or (symbol? x) (boolean? x)))

;; XXX: Are file-system-labels all that good?
;; Could a block-device record be better, instead?
(define (file-system-label-or-boolean? x)
  (or (file-system-label? x) (boolean? x)))

;; TODO: Create wrapper record for block-device.
(define (uuid-or-string-or-boolean? x)
  (or (uuid? x) (string? x) (boolean? x)))

(define-configuration/no-serialization bootloader-target
  (type symbol "What target this record describes, e.g. 'esp or 'disk.")
  (expected? (boolean #f) "TODO")
  (path (string-or-boolean #f) "TODO")
  (offset (symbol-or-boolean #f) "TODO")
  (device
   (uuid-or-string-or-boolean #f)
   "Refers to a physical device or partition.  A string is interpreted
as a block device.  Note that block devices can vary per boot and may
not exist at boot-time.  The find-partition-uuid procedure returns a
block device's UUID.")
  (file-system
   (string-or-boolean #f)
   "Set the type of the file system, in case it isn't being detected
properly, or it is unmounted during bootloader installation.  See also
the find-file-system and uuid->file-system procedures."))

(define-condition-type &target-error &error target-error?
  (type target-error-type)
  (targets target-error-targets))

;; XXX: Use a more appropriate name than FS?
(define (find-mount block-device-or-fs)
  "Return the <mount> record with source BLOCK-DEVICE-OR-FS, or #f
otherwise.  An FS could be efivarsfs, cgroup etc.."
  (define (block-device-or-fs? mount)
    (and (string=? block-device-or-fs (mount-source mount)) mount))
  ;; A mount source is either a block device or an FS.
  (when (and (not (string-prefix? "/dev/" block-device-or-fs))
             (or (string-contains "/" block-device-or-fs)
                 (string=? "none" block-device-or-fs)))
    (error (G_ "not a block device with mount~%") block-device-or-fs))
  (any block-device-or-fs? (mounts)))

(define (find-file-system block-device)
  "Detects the type of a given block device.  Return #f if not found."
  (and=> (find-mount block-device) mount-type))

(define (label->uuid label)
  (and=> (find-partition-by-label (file-system-label->string label))
         read-partition-uuid))

(define (uuid->file-system uuid)
  "Returns the UUID's type as a string.  Does not depend on current
mounts, unlike find-file-system.  Use together with the find-uuid, or
label->uuid procedure."
  (symbol->string (uuid-type uuid)))

;; TODO: Test together with find-mount.
(define (mount-point->block-device point)
  "Return the block device mounted on POINT, or #f otherwise."
  (define (point? mount)
    (and (string=? point (mount-point mount)) (mount-source mount)))
  ;; A mount point is an absolute path.
  (unless (string-prefix? "/" point)
    (error (G_ "mount point is not an absolute path~%") point))
  (any point? (mounts)))

(define (pathcat p1 p2)
  (string-append (string-trim-right p1 #\/) "/" (string-trim p2 #\/)))

(define* (get-target-of-type type targets #:optional require?)
  "Finds a target in TARGETS of type TYPE, returns #f if REQUIRE? is #f,
and provides an error otherwise."
  (define (type? target)
    (eq? type (bootloader-target-type target)))
  (match (filter type? targets)
    ((target _ ...) target)
    (_ (and require?
            (raise
              (condition
                (&message (message (G_ "required, but not provided")))
                (&target-error (type type) (targets targets))))))))

(define (parent-of target targets)
  "Resolve the parent of TARGET in TARGETS, return #f if orphan."
  (and=> (bootloader-target-offset target)
         (cut get-target-of-type <> targets #t)))

(define (unfold-pathcat target targets)
  "Find the full VFS path of TARGET."
  (let ((quit (lambda (t) (not (and=> t bootloader-target-path))))
        (parent-of (cut parent-of <> targets)))
    (reduce pathcat #f
      (unfold quit bootloader-target-path parent-of target))))

(define (target-base? t)
  (or (not t) (match-record t <bootloader-target>
                (expected? offset device)
                (or device (not offset) expected?))))

(define (type-major? target) (memq target '(root esp disk)))

(define (ensure types targets end)
  (let* ((used-in (cute unfold end identity (cut parent-of <> targets) <>))
         (cons-in (lambda (t) (cons t (used-in t))))
         (ensure (map (cut get-target-of-type <> targets #t) types)))
    (filter identity (apply append (map cons-in ensure)))))

(define* (ensure-target-types types targets #:optional (base? #f))
  "Ensures all TYPES are provided in TARGETS.  Returns #t iff every ensured
target and its requirements are fully provided.  Errors out when a required TYPE
isn't provided.  When BASE?, only ensure path requirements up to a device."
  (let ((base (if base? target-base? not)))
    (not (any bootloader-target-expected? (ensure types targets base)))))

(define (ensure-majors types targets)
  "Errors out when a required TYPE isn't provided, or when use of multiple major
targets is detected."
  (let* ((all (map bootloader-target-type
                   (ensure types targets target-base?)))
         (majors (delete-duplicates (filter type-major? all) eq?)))
    (if (< (length majors) 2) #t
      (raise (condition (&message (message (G_ "multiple major targets used")))
                        (&target-error (type majors) (targets targets)))))))



(define (gbegin . gex)
  "Sequence provided g-expressions."
  (case (length gex) ((0) #f) ((1) (car gex)) (else #~(begin #$@gex))))

;; syntax matching on free literals breaks easily, so bind them
(define-syntax-rule (define-literal id) (define-syntax id (syntax-rules ())))
(define-literal :path)
(define-literal :devpath)
(define-literal :device)
(define-literal :fs)
(define-literal :label)
(define-literal :uuid)

(define-syntax with-targets
  (cut syntax-case <> ()
    ((_ targets-expr block ...)
     (let* ((genvars (compose generate-temporaries make-list))
            (targets (car (genvars 1))))
       (define (resolve in target base)
         (with-syntax ((target target) (base base) (targets targets))
           (syntax-case in
             (:path :devpath :device :fs :label :uuid)
             ((name _) (not (identifier? #'name))
              #`(_ (syntax-error "binds must be to identifiers" #,in)))
             ((name :device)
              #'(name (and (string? (bootloader-target-device base))
                           (bootloader-target-device base))))
             ((name :label)
              #'(name (and (string? (bootloader-target-device base))
                           (bootloader-target-device base))))
             ((name :uuid)
              #'(name (and (uuid? (bootloader-target-device base))
                           (bootloader-target-device base))))
             ((name :fs) #'(name (bootloader-target-file-system base)))
             ((name :path) #'(name (unfold-pathcat target targets)))
             ((name :devpath)
              #'(name (if (target-base? target)
                          "/"
                          (pathcat "/" (bootloader-target-path target)))))
             (_ #`(_ (syntax-error "invalid binding spec" #,in))))))

       (define (binds spec)
         (syntax-case spec (=>)
           ((type => binds ...)
            (with-syntax (((target base) (genvars 2)) (targets targets))
              (append
                #`((get (lambda (t) (get-target-of-type t targets #t)))
                   (target (get type))
                   (base (if (target-base? target)
                             target
                             (get (bootloader-target-offset target)))))
                (map (cut resolve <> #'target #'base) #'(binds ...)))))
           (_ #f)))

       (define blocks
         (cut syntax-case <> ()
           ((spec ... expr)
            (let* ((path? (cut syntax-case <> (:path) ((_ :path) #t) (_ #f)))
                   (qualified? (cut syntax-case <> (=>)
                                 ((_ => spec ...)
                                  (any path? #'(spec ...)))
                                 (_ #f)))
                   (specs #'(spec ...))
                   (lets (apply append (filter-map binds specs)))
                   (type (cut syntax-case <> (=>)
                           ((t => _ ...) #'t) (t #'t))))
              (receive (full part) (partition qualified? specs)
                #`(and (ensure-majors (list #,@(map type specs)) #,targets)
                       (ensure-target-types (list #,@(map type part))
                                            #,targets #t)
                       (ensure-target-types (list #,@(map type full))
                                            #,targets #f)
                       (let* #,lets expr)))))
           (bad #'(syntax-error "malformed block" bad))))
       "Using the list TARGETS, evaluate and sequence each BLOCK to produce a
gexp.  BLOCK is a set of SPECs followed by an EXPR (evaluating to a gexp).
Each SPEC denotes a type of target to guard EXPR on their existance and
full-qualification.  This procedure is linear in regard to BLOCKs.

SPEC may be of the following forms:
@itemize
@item 'TYPE Requires TYPE to be fully present or promised. Errors otherwise.
@item ('TYPE => (VAR COMPONENT) ...): As type, but also binds variables. TYPE's
      COMPONENT is bound to the variable VAR as described below.
@end itemize

Available COMPONENTs are:
@itemize
@item :path (fully-qualified)
@item :devpath (relative from device)
@item :device (auto-detected from uuid and label if not user-provided)
@item :fs
@item :label
@item :uuid
@end itemize

Note that installers may be called multiple times with different targets being
fully-qualified.  To ensure that targets aren't installed multiple times, make sure
that each BLOCK ensures at least one major target, either directly or indirectly.
Likewise, at most one major target should be ensured per BLOCK, under the same
conditions.  Major targets originate from disk image handling, and are currently:
@itemize
@item disk
@item root
@item esp
@end itemize"
       #`(let ((#,targets targets-expr))
           (apply gbegin (filter identity
                                 (list #,@(map blocks #'(block ...))))))))
    (bad #'(syntax-error "must provide targets" bad))))


;;;
;;; Bootloader configuration record.
;;;

;; The <bootloader-configuration> record contains bootloader independent
;; configuration used to fill bootloader configuration file.

;; Based on report-duplicate-field-specifier from (guix records).
(define (report-duplicate-type-field targets)
  "Report the first target with duplicate type among TARGETS."
  (let loop ((targets targets)
             (seen    '()))
    (match targets
      ((target rest ...)
       (let ((type (bootloader-target-type target)))
         (when (memq type seen)
           (error loc (G_ "target with duplicate type~%") duplicate))
         (loop rest (cons type seen))))
      (() #t))))

(define-with-syntax-properties (warn-update-targets (value properties))
  (let ((targets (wrap-element value))
        (loc (source-properties->location properties)))
    (define string->target
      (match-lambda
        ((? bootloader-target? target) target)
        ((? string? s) (if (string-prefix? "/dev" s)
                           (if (string-match ".+p[0-9]+$" s)
                               (bootloader-target
                                 (type 'part)
                                 (device s))
                               (bootloader-target
                                 (type 'disk)
                                 (device s)))
                           (bootloader-target
                             (type 'esp)
                             (offset 'root)
                             (path s))))
        (x (error loc (G_ "invalid target '~a'~%") x))))

    ;; XXX: Should this be an error?
    (when (any string? targets)
      (warning loc (G_ "the 'targets' field should now contain \
<bootloader-target> records, inferring a best guess, this might break!~%")))
    (let* ((targets (map string->target targets)))
      (report-duplicate-type-field targets)
      targets)))

(define-record-type* <bootloader-configuration>
  bootloader-configuration make-bootloader-configuration
  bootloader-configuration?
  (bootloader
   bootloader-configuration-bootloader)   ;<bootloader>
  (targets               bootloader-configuration-targets
                         (default '())    ;list of strings
                         (sanitize warn-update-targets))
  (menu-entries          bootloader-configuration-menu-entries
                         (default '()))   ;list of <menu-entry>
  (default-entry         bootloader-configuration-default-entry
                         (default 0))     ;integer
  (efi-removable?        bootloader-configuration-efi-removable?
                         (default #f))    ;bool
  (32bit?                bootloader-configuration-32bit?
                         (default #f))    ;bool
  (keypair               bootloader-configuration-keypair
                         (default #f))    ;(cert . priv) pair
  (timeout               bootloader-configuration-timeout
                         (default 5))     ;seconds as integer
  (keyboard-layout       bootloader-configuration-keyboard-layout
                         (default #f))    ;<keyboard-layout> | #f
  (theme                 bootloader-configuration-theme
                         (default #f))    ;bootloader-specific theme
  (terminal-outputs      bootloader-configuration-terminal-outputs
                         (default #f))    ;list of symbols | #f (default outs)
  (terminal-inputs       bootloader-configuration-terminal-inputs
                         (default #f))    ;list of symbols | #f (default ins)
  (serial-unit           bootloader-configuration-serial-unit
                         (default #f))    ;integer | #f
  (serial-speed          bootloader-configuration-serial-speed
                         (default #f))    ;integer | #f
  (device-tree-support?  bootloader-configuration-device-tree-support?
                         (default #t))    ;boolean
  (extra-initrd          bootloader-configuration-extra-initrd
                         (default #f)))   ;string | #f


;;;
;;; Bootloader installation paths.
;;;

(define (target-overrides . layers)
  (let* ((types (flat-map (cute map bootloader-target-type <>) layers))
         ;; TODO: use loop instead of fold for early termination.
         (pred (lambda (type layer found)
                 (or found (get-target-of-type type layer))))
         (find (lambda (type) (fold (cute pred type <> <>) #f layers))))
    (filter identity (map find (delete-duplicates types)))))

(define (normalize targets)
  "Augments TARGETS with filesystem information at runtime, allowing
users to specify a lot less information.  Puts TARGETS into a normal
form, where each path is fully specified up to a device offset."
  (define (mass m)
    `((,(mount-source m) . ,m)
      (,(mount-point m) . ,m)))

  (define (arborify target targets)
    (let* ((up (lambda (t) (and t (parent-of t targets))))
           (proto (unfold target-base? identity up (up target) list))
           (chain (reverse (cons target proto))))
      (bootloader-target
        (inherit target)
        (offset (and=> (car chain) bootloader-target-type))
        (path (reduce pathcat #f (map bootloader-target-path (cdr chain)))))))

  (let ((amounts (delay (apply append (map mass (mounts))))))
    (define (assoc-mnt f)
      (lambda (v) (and=> (assoc-ref (force amounts) v) f)))

    (define (scrape target)
      (match-record target <bootloader-target>
        (expected? path offset device file-system)
        (if expected? target
          (bootloader-target
            (inherit target)
            (device (or device
                        (and path ((assoc-mnt mount-source)
                                   (unfold-pathcat target targets)))))
            (file-system (or file-system
                             (match device
                               ((? string?) ((assoc-mnt mount-type) device))
                               ((? uuid?) (uuid->file-system device))
                               (_ #f))))
            (offset (and path offset))
            (path (or path (and=> device (assoc-mnt mount-point))))))))

    (let ((mid (map scrape targets)))
      (map (cut arborify <> mid) mid))))

(define* (bootloader-configuration->gexp bootloader-config args #:key
                                          (root-offset "/") (overrides '()))
  "Returns a gexp to install BOOTLOADER-CONFIG to its targets, passing ARGS
to each installer alongside the additional #:bootloader-config keyword
arguments.  Target OVERRIDES are applied and all path targets have ROOT-OFFSET
applied.  The following keyword arguments are expected in ARGS:
@enumerate
@item current-boot-alternative
@item old-boot-alternatives
@item locale (from bootmeta)
@item store-directory-prefix (from bootmeta)
@item store-crypto-devices (from bootmeta)
@end enumerate"
  (let* ((bootloader (bootloader-configuration-bootloader bootloader-config))
         (installer (bootloader-installer bootloader))
         (auto-targets (list (bootloader-target
                               (type 'root)
                               (path root-offset)
                               (offset #f))))
         (targets (target-overrides
                    overrides
                    (bootloader-configuration-targets bootloader-config)
                    auto-targets
                    (bootloader-default-targets bootloader)))
         (conf (bootloader-configuration
                 (inherit bootloader-config)
                 (targets (normalize targets)))))
    (apply installer #:bootloader-config conf args)))

(define (bootloader-configurations->gexp bootloader-configs . rest)
  (apply gbegin (filter-map (cut apply bootloader-configuration->gexp <> rest)
                            bootloader-configs)))

;; In lieu of exporting bootloader-configuration and menu-entry RTDs.
(define-syntax match-bootloader-configuration
  (syntax-rules ()
    "Bind each BOOTLOADER-CONFIGURATION field in FIELDS."
    ((_ bootloader-configuration (fields ...) body ...)
     (match-record bootloader-configuration <bootloader-configuration>
                   (fields ...) body ...))))

(define-syntax match-menu-entry
  (syntax-rules ()
    "Bind each MENU-ENTRY field in FIELDS."
    ((_ menu-entry (fields ...) body ...)
     (match-record menu-entry <menu-entry> (fields ...) body ...))))


;;;
;;; Bootloader installation to ESP.
;;;

;; systems currently supported by efi-arch. should be used for packages relying
;; on it.
(define %efi-supported-systems
  '("i686-linux" "x86_64-linux" "armhf-linux" "aarch64-linux" "riscv64-linux"))

(define* (efi-arch #:key (target (or (%current-target-system) (%current-system)))
                         (32? #f))
  "Returns the UEFI architecture name for the current target, in lowercase."
  (cond ((target-x86-32? target)  "ia32")
        ((target-x86-64? target)  (if 32? "ia32" "x64"))
        ((target-arm32? target)   "arm")
        ((target-aarch64? target) (if 32? "arm" "aa64"))
        ((target-riscv64? target) (if 32? "riscv32" "riscv64"))
        (else (raise (formatted-message (G_ "no UEFI standard arch for ~a!")
                                        target)))))

(define (lazy-efibootmgr)
  "Lazy-loaded efibootmgr package, in order to prevent circular refs."
  (module-ref (resolve-interface '(gnu packages linux)) 'efibootmgr))

(define (install-efi bootloader-config plan)
  "Returns a gexp installing PLAN to the ESP, as denoted by the 'vendir target.
PLAN is a gexp of a list of '(BUILDER DEST-BASENAME . LABEL) triples, that
should be in boot order.  If the user selects a removable bootloader, only the
first entry in PLAN is used."
  (match-record bootloader-config <bootloader-configuration>
    (targets efi-removable? 32bit?)
    (if efi-removable?
      ;; Hard code the output location to a well-known path recognized by
      ;; compliant firmware.  See "3.5.1.1 Removable Media Boot Behaviour":
      ;; http://www.uefi.org/sites/default/files/resources/UEFI%20Spec%202_6.pdf
      (with-targets targets
        (('esp => (path :path))
         #~(let ((boot #$(string-append path "/EFI/BOOT"))
                 (arch #$(string-upcase (efi-arch #:32? 32bit?)))
                 (builder (car (car #$plan))))
             (mkdir-p boot)
             ;; Only realize the first planspec.
             (builder (string-append boot "/BOOT" arch ".EFI")))))
      ;; Install normally if not configured as removable.
      (with-targets targets
        (('vendir => (vendir :path) (loader :devpath) (disk :device))
         #~(install-efi #+(file-append (lazy-efibootmgr) "/sbin/efibootmgr")
                        #$vendir #$loader #$disk #$plan))))))