Augment build-expression->derivation' with #:modules; add http-fetch'.

* guix/derivations.scm (imported-modules): New procedure.
  (build-expression->derivation): New keyword argument `modules'.
  Use `imported-modules' when MODULES is non-empty, and pass it with
  `-L' to GUILE.

* guix/build/http.scm, guix/http.scm, tests/builders.scm: New files.

guix/build/http.scm

@@ -0,0 +1,42 @@
+;;; Guix --- Nix package management from Guile.         -*- coding: utf-8 -*-
+;;; Copyright (C) 2012 Ludovic Courtès <ludo@gnu.org>
+;;;
+;;; This file is part of Guix.
+;;;
+;;; Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build http)
+  #:use-module (web client)
+  #:use-module (web uri)
+  #:use-module (rnrs io ports)
+  #:use-module (srfi srfi-11)
+  #:export (http-fetch))
+
+;;; Commentary:
+;;;
+;;; Fetch data such as tarballs over HTTP (builder-side code).
+;;;
+;;; Code:
+
+(define (http-fetch url file)
+  "Fetch data from URL and write it to FILE.  Return FILE on success."
+
+  ;; FIXME: Use a variant of `http-get' that returns a port instead of
+  ;; loading everything in memory.
+  (let-values (((resp bv)
+                (http-get (string->uri url) #:decode-body? #f)))
+    (call-with-output-file file
+      (lambda (p)
+        (put-bytevector p bv))))
+  file)

guix/derivations.scm

@@ -418,9 +418,27 @@ (define (parent-dirs file-name)
     (build-expression->derivation store name (%current-system)
                                   builder files)))
 
+(define* (imported-modules store modules
+                           #:key (name "module-import")
+                           (system (%current-system)))
+  "Return a derivation that contains the source files of MODULES, a list of
+module names such as `(ice-9 q)'.  All of MODULES must be in the current
+search path."
+  ;; TODO: Determine the closure of MODULES, build the `.go' files,
+  ;; canonicalize the source files through read/write, etc.
+  (let ((files (map (lambda (m)
+                      (let ((f (string-append
+                                (string-join (map symbol->string m) "/")
+                                ".scm")))
+                        (cons f (search-path %load-path f))))
+                    modules)))
+    (imported-files store files #:name name #:system system)))
+
+
 (define* (build-expression->derivation store name system exp inputs
                                        #:key (outputs '("out"))
-                                       hash hash-algo)
+                                       hash hash-algo
+                                       (modules '()))
   "Return a derivation that executes Scheme expression EXP as a builder for
 derivation NAME.  INPUTS must be a list of string/derivation-path pairs.  EXP
 is evaluated in an environment where %OUTPUT is bound to the main output
@@ -449,10 +467,19 @@ (define %build-inputs
                                       (string-append name "-guile-builder")
                                       (string-append (object->string prologue)
                                                      (object->string exp))
-                                      (map cdr inputs))))
-    (derivation store name system guile `("--no-auto-compile" ,builder)
+                                      (map cdr inputs)))
+         (mod-drv  (if (null? modules)
+                       #f
+                       (imported-modules store modules)))
+         (mod-dir  (and mod-drv
+                        (derivation-path->output-path mod-drv))))
+    (derivation store name system guile
+                `("--no-auto-compile"
+                  ,@(if mod-dir `("-L" ,mod-dir) '())
+                  ,builder)
                 '(("HOME" . "/homeless"))
                 `((,(%guile-for-build))
-                  (,builder))
+                  (,builder)
+                  ,@(if mod-drv `((,mod-drv)) '()))
                 #:hash hash #:hash-algo hash-algo
                 #:outputs outputs)))

guix/http.scm

@@ -0,0 +1,45 @@
+;;; Guix --- Nix package management from Guile.         -*- coding: utf-8 -*-
+;;; Copyright (C) 2012 Ludovic Courtès <ludo@gnu.org>
+;;;
+;;; This file is part of Guix.
+;;;
+;;; Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix http)
+  #:use-module (guix derivations)
+  #:use-module (guix utils)
+  #:export (http-fetch))
+
+;;; Commentary:
+;;;
+;;; Produce fixed-output derivations with data fetched over HTTP.
+;;;
+;;; Code:
+
+(define* (http-fetch store url hash-algo hash
+                     #:key name (system (%current-system)))
+  "Return the path of a fixed-output derivation in STORE that fetches URL,
+which is expected to have hash HASH of type HASH-ALGO (a symbol).  By
+default, the file name is the base name of URL; optionally, NAME can specify
+a different file name."
+  (define builder
+    `(begin
+       (use-modules (guix build http))
+       (http-fetch ,url %output)))
+
+  (build-expression->derivation store (or name (basename url)) system
+                                builder '()
+                                #:hash-algo hash-algo
+                                #:hash hash
+                                #:modules '((guix build http))))

tests/builders.scm

@@ -0,0 +1,50 @@
+;;; Guix --- Nix package management from Guile.         -*- coding: utf-8 -*-
+;;; Copyright (C) 2012 Ludovic Courtès <ludo@gnu.org>
+;;;
+;;; This file is part of Guix.
+;;;
+;;; Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+
+(define-module (test-builders)
+  #:use-module (guix http)
+  #:use-module (guix store)
+  #:use-module (guix utils)
+  #:use-module (guix derivations)
+  #:use-module (srfi srfi-1)
+  #:use-module (srfi srfi-64))
+
+;; Test the higher-level builders.
+
+(define %store
+  (false-if-exception (open-connection)))
+
+(test-begin "builders")
+
+(test-assert "http-fetch"
+  (let* ((url      "http://ftp.gnu.org/gnu/hello/hello-2.8.tar.gz")
+         (hash     (nix-base32-string->bytevector
+                    "0wqd8sjmxfskrflaxywc7gqw7sfawrfvdxd9skxawzfgyy0pzdz6"))
+         (drv-path (http-fetch %store url 'sha256 hash)))
+    (and (build-derivations %store (list drv-path))
+         (file-exists? (derivation-path->output-path drv-path)))))
+
+(test-end "builders")
+
+
+(exit (= (test-runner-fail-count (test-runner-current)) 0))
+
+;;; Local Variables:
+;;; eval: (put 'test-assert 'scheme-indent-function 1)
+;;; End: