Add (guix monad-repl).

* guix/monad-repl.scm: New file.
* guix.scm: Add it.
* Makefile.am (MODULES): Add it.
* doc/guix.texi (The Store Monad): Document it.

Makefile.am

@@ -37,6 +37,7 @@ MODULES =					\
   guix/download.scm				\
   guix/git-download.scm				\
   guix/monads.scm				\
+  guix/monad-repl.scm				\
   guix/gexp.scm					\
   guix/profiles.scm				\
   guix/serialization.scm			\

doc/guix.texi

@@ -1937,6 +1937,33 @@ effect, one must use @code{run-with-store}:
 @result{} /gnu/store/...-profile.sh
 @end example
 
+Note that the @code{(guix monad-repl)} module extends Guile's REPL with
+new ``meta-commands'' to make it easier to deal with monadic procedures:
+@code{run-in-store}, and @code{enter-store-monad}.  The former, is used
+to ``run'' a single monadic value through the store:
+
+@example
+scheme@@(guile-user)> ,run-in-store (package->derivation hello)
+$1 = #<derivation /gnu/store/@dots{}-hello-2.9.drv => @dots{}>
+@end example
+
+The latter enters a recursive REPL, where all the return values are
+automatically run through the store:
+
+@example
+scheme@@(guile-user)> ,enter-store-monad
+store-monad@@(guile-user) [1]> (package->derivation hello)
+$2 = #<derivation /gnu/store/@dots{}-hello-2.9.drv => @dots{}>
+store-monad@@(guile-user) [1]> (text-file "foo" "Hello!")
+$3 = "/gnu/store/@dots{}-foo"
+store-monad@@(guile-user) [1]> ,q
+scheme@@(guile-user)>
+@end example
+
+@noindent
+Note that non-monadic values cannot be returned in the
+@code{store-monad} REPL.
+
 The main syntactic forms to deal with monads in general are described
 below.
 

guix.scm

@@ -30,6 +30,7 @@ (define %public-modules
         ftp-client
         gexp
         monads
+        monad-repl
         packages
         store
         utils))

guix/monad-repl.scm

@@ -0,0 +1,81 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2014 Ludovic Courtès <ludo@gnu.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix monad-repl)
+  #:use-module (guix store)
+  #:use-module (guix monads)
+  #:use-module (ice-9 pretty-print)
+  #:use-module (system repl repl)
+  #:use-module (system repl common)
+  #:use-module (system repl command)
+  #:use-module (system base language)
+  #:use-module (system base compile)
+  #:use-module (srfi srfi-26)
+  #:export (run-in-store
+            enter-store-monad))
+
+;;; Comment:
+;;;
+;;; This modules provides a couple of REPL meta-commands that make it easier
+;;; to work with monadic procedures in the store monad.
+;;;
+;;; Code:
+
+(define* (monad-language monad run #:optional (name 'monad))
+  "Return a language with a special evaluator that causes monadic values
+ to be \"run\" in MONAD using procedure RUN."
+  (let ((scheme (lookup-language 'scheme)))
+    (define (evaluate-monadic-expression exp env)
+      (let ((mvalue (compile exp #:to 'value #:env env)))
+        (run mvalue)))
+
+    (make-language #:name name
+                   #:title "Monad"
+                   #:reader (language-reader scheme)
+                   #:compilers (language-compilers scheme)
+                   #:decompilers (language-decompilers scheme)
+                   #:evaluator evaluate-monadic-expression
+                   #:printer (language-printer scheme)
+                   #:make-default-environment
+                   (language-make-default-environment scheme))))
+
+(define (store-monad-language)
+  "Return a compiler language for the store monad."
+  (let ((store (open-connection)))
+    (monad-language %store-monad
+                    (cut run-with-store store <>)
+                    'store-monad)))
+
+(define-meta-command ((run-in-store guix) repl (form))
+  "run-in-store EXP
+Run EXP through the store monad."
+  (let ((value (with-store store
+                 (run-with-store store (repl-eval repl form)))))
+    (run-hook before-print-hook value)
+    (pretty-print value)))
+
+(define-meta-command ((enter-store-monad guix) repl)
+  "enter-store-monad
+Enter a REPL for values in the store monad."
+  (let ((new (make-repl (store-monad-language))))
+    ;; Force interpretation so that our specially-crafted language evaluator
+    ;; is actually used.
+    (repl-option-set! new 'interp #t)
+    (run-repl new)))
+
+;;; monad-repl.scm ends here