mirror of
https://git.in.rschanz.org/ryan77627/guix.git
synced 2024-11-07 07:26:13 -05:00
233e76769a
Change all license headers, except guix/build/* and ld-wrapper.scm, with
this code:
(use-modules (guix build utils)
(srfi srfi-1))
(fluid-set! %default-port-encoding "UTF-8")
(substitute* (remove (lambda (f)
(or (string-contains f ".tar.")
(string-contains f ".git/")
(string-contains f ".so")
(string-suffix? ".o" f)
(string-suffix? ".a" f)
(string-suffix? ".go" f)
(string-suffix? ".pdf" f)
(string-suffix? ".png" f)
(string-suffix? ".info" f)
(equal? (basename f) "guix-daemon")
(equal? (basename f) "nix-setuid-helper")
(string-contains f "nix-upstream/")
(string-contains f "distro/packages/bootstrap/")))
(find-files "." "\\.[a-z]+$"))
(("^([[:graph:]]+) This file is part of Guix." _ comment-start)
(string-append comment-start " This file is part of GNU Guix."))
(("^([[:graph:]]+) Guix --- Nix package management.*" _ comment-start)
(string-append comment-start
" GNU Guix --- Functional package management for GNU\n"))
(("^([[:graph:]]+) Guix is " _ comment-start)
(string-append comment-start " GNU Guix is "))
(("^([[:graph:]]+) along with Guix." _ comment-start)
(string-append comment-start " along with GNU Guix."))
(("^([[:graph:]]+) Copyright \\(C\\)" _ comment-start)
(string-append comment-start " Copyright ©")))
Change headers using C-style comments manually.
137 lines
4.2 KiB
Scheme
137 lines
4.2 KiB
Scheme
#!/bin/sh
|
||
# aside from this initial boilerplate, this is actually -*- scheme -*- code
|
||
|
||
prefix="@prefix@"
|
||
datarootdir="@datarootdir@"
|
||
|
||
GUILE_LOAD_COMPILED_PATH="@guilemoduledir@:$GUILE_LOAD_COMPILED_PATH"
|
||
export GUILE_LOAD_COMPILED_PATH
|
||
|
||
main='(module-ref (resolve-interface '\''(guix-import)) '\'guix-import')'
|
||
exec ${GUILE-@GUILE@} -L "@guilemoduledir@" -l "$0" \
|
||
-c "(apply $main (cdr (command-line)))" "$@"
|
||
!#
|
||
;;; GNU Guix --- Functional package management for GNU
|
||
;;; Copyright © 2012, 2013 Ludovic Courtès <ludo@gnu.org>
|
||
;;;
|
||
;;; This file is part of GNU Guix.
|
||
;;;
|
||
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
||
;;; under the terms of the GNU General Public License as published by
|
||
;;; the Free Software Foundation; either version 3 of the License, or (at
|
||
;;; your option) any later version.
|
||
;;;
|
||
;;; GNU Guix is distributed in the hope that it will be useful, but
|
||
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;;; GNU General Public License for more details.
|
||
;;;
|
||
;;; You should have received a copy of the GNU General Public License
|
||
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
||
|
||
(define-module (guix-import)
|
||
#:use-module (guix ui)
|
||
#:use-module (guix snix)
|
||
#:use-module (guix utils)
|
||
#:use-module (srfi srfi-1)
|
||
#:use-module (srfi srfi-11)
|
||
#:use-module (srfi srfi-26)
|
||
#:use-module (srfi srfi-37)
|
||
#:use-module (ice-9 match)
|
||
#:use-module (ice-9 pretty-print)
|
||
#:export (guix-import))
|
||
|
||
|
||
;;;
|
||
;;; Helper.
|
||
;;;
|
||
|
||
(define (newline-rewriting-port output)
|
||
"Return an output port that rewrites strings containing the \\n escape
|
||
to an actual newline. This works around the behavior of `pretty-print'
|
||
and `write', which output these as \\n instead of actual newlines,
|
||
whereas we want the `description' field to contain actual newlines
|
||
rather than \\n."
|
||
(define (write-string str)
|
||
(let loop ((chars (string->list str)))
|
||
(match chars
|
||
(()
|
||
#t)
|
||
((#\\ #\n rest ...)
|
||
(newline output)
|
||
(loop rest))
|
||
((chr rest ...)
|
||
(write-char chr output)
|
||
(loop rest)))))
|
||
|
||
(make-soft-port (vector (cut write-char <>)
|
||
write-string
|
||
(lambda _ #t) ; flush
|
||
#f
|
||
(lambda _ #t) ; close
|
||
#f)
|
||
"w"))
|
||
|
||
|
||
;;;
|
||
;;; Command-line options.
|
||
;;;
|
||
|
||
(define %default-options
|
||
'())
|
||
|
||
(define (show-help)
|
||
(display (_ "Usage: guix-import NIXPKGS ATTRIBUTE
|
||
Import and convert the Nix expression ATTRIBUTE of NIXPKGS.\n"))
|
||
(display (_ "
|
||
-h, --help display this help and exit"))
|
||
(display (_ "
|
||
-V, --version display version information and exit"))
|
||
(newline)
|
||
(show-bug-report-information))
|
||
|
||
(define %options
|
||
;; Specification of the command-line options.
|
||
(list (option '(#\h "help") #f #f
|
||
(lambda args
|
||
(show-help)
|
||
(exit 0)))
|
||
(option '(#\V "version") #f #f
|
||
(lambda args
|
||
(show-version-and-exit "guix-import")))))
|
||
|
||
|
||
;;;
|
||
;;; Entry point.
|
||
;;;
|
||
|
||
(define (guix-import . args)
|
||
(define (parse-options)
|
||
;; Return the alist of option values.
|
||
(args-fold args %options
|
||
(lambda (opt name arg result)
|
||
(leave (_ "~A: unrecognized option~%") name))
|
||
(lambda (arg result)
|
||
(alist-cons 'argument arg result))
|
||
%default-options))
|
||
|
||
(setlocale LC_ALL "")
|
||
(textdomain "guix")
|
||
(setvbuf (current-output-port) _IOLBF)
|
||
(setvbuf (current-error-port) _IOLBF)
|
||
|
||
(let* ((opts (parse-options))
|
||
(args (filter-map (match-lambda
|
||
(('argument . value)
|
||
value)
|
||
(_ #f))
|
||
(reverse opts))))
|
||
(match args
|
||
((nixpkgs attribute)
|
||
(let-values (((expr loc)
|
||
(nixpkgs->guix-package nixpkgs attribute)))
|
||
(format #t ";; converted from ~a:~a~%~%"
|
||
(location-file loc) (location-line loc))
|
||
(pretty-print expr (newline-rewriting-port (current-output-port)))))
|
||
(_
|
||
(leave (_ "wrong number of arguments~%"))))))
|