mirror of
https://git.in.rschanz.org/ryan77627/guix.git
synced 2024-12-24 05:18:07 -05:00
d4053c710b
* gnu/services/shepherd.scm (dmd-root-service-type, %dmd-root-service)
(dmd-service-type, <dmd-service>, dmd-service, dmd-service?)
(make-dmd-service, dmd-service-documentation, dmd-service-provision)
(dmd-service-requirement, dmd-service-respawn, dmd-service-start)
(dmd-service-stop, dmd-service-auto-start?, dmd-service-modules)
(dmd-service-imported-modules, dmd-service-file-name, dmd-service-file)
(dmd-service-back-edges): Rename to...
(shepherd-root-service-type, %shepherd-root-service, shepherd-service-type)
(<shepherd-service>, shepherd-service, shepherd-service?)
(make-shepherd-service, shepherd-service-documentation)
(shepherd-service-provision, shepherd-service-requirement)
(shepherd-service-respawn, shepherd-service-start)
(shepherd-service-stop, shepherd-service-auto-start?)
(shepherd-service-modules, shepherd-service-imported-modules)
(shepherd-service-file-name, shepherd-service-file)
(shepherd-service-back-edges): ...this
* gnu/services.scm: Adjust comments.
* gnu/services/avahi.scm (avahi-dmd-service): Rename to...
(avahi-shepherd-service): ... this.
* gnu/services/base.scm (%root-file-system-dmd-service)
(file-system->dmd-service-name, mapped-device->dmd-service-name)
(dependency->dmd-service-name, file-system-dmd-service)
(mingetty-dmd-service, nscd-dmd-service, guix-dmd-service)
(guix-publish-dmd-service, udev-dmd-service, gpm-dmd-service): Rename to...
(%root-file-system-shepherd-service)
(file-system->shepherd-service-name, mapped-device->shepherd-service-name)
(dependency->shepherd-service-name, file-system-shepherd-service)
(mingetty-shepherd-service, nscd-shepherd-service, guix-shepherd-service)
(guix-publish-shepherd-service, udev-shepherd-service)
(gpm-shepherd-service): ... this.
* gnu/services/databases.scm (postgresql-dmd-service): Rename to...
(postgresql-shepherd-service): ... this.
* gnu/services/desktop.scm (upower-dmd-service, elogind-dmd-service):
Rename to...
(upower-shepherd-service, elogind-shepherd-service): ... this.
* gnu/services/dbus.scm (dbus-dmd-service): Rename to...
(dbus-shepherd-service): ... this.
* gnu/services/lirc.scm (lirc-dmd-service): Rename to...
(lirc-shepherd-service): ... this.
* gnu/services/mail.scm (dovecot-dmd-service): Rename to...
(dovecot-shepherd-service): ... this.
* gnu/services/networking.scm (ntp-dmd-service, tor-dmd-service)
(bitlbee-dmd-service, wicd-dmd-service, network-manager-dmd-service): Rename to...
(dbus-shepherd-service): ... this.
* gnu/services/ssh.scm (lsh-dmd-service): Rename to...
(lsh-shepherd-service): ... this.
* gnu/services/web.scm (nginx-dmd-service): Rename to...
(nginx-shepherd-service): ... this.
* gnu/services/xorg.scm (slim-dmd-service): Rename to...
(slim-shepherd-service): ... this.
* gnu/system.scm (essential-services): Use '%shepherd-root-service'.
* gnu/system/install.scm (cow-store-service-type): Adjust accordingly.
* guix/scripts/system.scm (dmd-service-node-label, dmd-service-node-type)
(export-dmd-graph): Likewise.
* tests/guix-system.sh: Likewise.
* tests/services.scm ("dmd-service-back-edges"): Rename to...
("shepherd-service-back-edges"): Adjust accordingly.
* doc/guix.texi: Likewise.
* doc/images/service-graph.dot: Use 'shepherd' service name.
124 lines
5.1 KiB
Scheme
124 lines
5.1 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
||
;;; Copyright © 2015 Ludovic Courtès <ludo@gnu.org>
|
||
;;;
|
||
;;; This file is part of GNU Guix.
|
||
;;;
|
||
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
||
;;; under the terms of the GNU General Public License as published by
|
||
;;; the Free Software Foundation; either version 3 of the License, or (at
|
||
;;; your option) any later version.
|
||
;;;
|
||
;;; GNU Guix is distributed in the hope that it will be useful, but
|
||
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;;; GNU General Public License for more details.
|
||
;;;
|
||
;;; You should have received a copy of the GNU General Public License
|
||
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
||
|
||
(define-module (test-services)
|
||
#:use-module (gnu services)
|
||
#:use-module (gnu services shepherd)
|
||
#:use-module (srfi srfi-1)
|
||
#:use-module (srfi srfi-26)
|
||
#:use-module (srfi srfi-34)
|
||
#:use-module (srfi srfi-64))
|
||
|
||
(test-begin "services")
|
||
|
||
(test-assert "service-back-edges"
|
||
(let* ((t1 (service-type (name 't1) (extensions '())
|
||
(compose +) (extend *)))
|
||
(t2 (service-type (name 't2)
|
||
(extensions
|
||
(list (service-extension t1 (const '()))))
|
||
(compose +) (extend *)))
|
||
(t3 (service-type (name 't3)
|
||
(extensions
|
||
(list (service-extension t2 identity)
|
||
(service-extension t1 list)))))
|
||
(s1 (service t1 #t))
|
||
(s2 (service t2 #t))
|
||
(s3 (service t3 #t))
|
||
(e (service-back-edges (list s1 s2 s3))))
|
||
(and (lset= eq? (e s1) (list s2 s3))
|
||
(lset= eq? (e s2) (list s3))
|
||
(null? (e s3)))))
|
||
|
||
(test-equal "fold-services"
|
||
;; Make sure 'fold-services' returns the right result. The numbers come
|
||
;; from services of type T3; 'xyz 60' comes from the service of type T2,
|
||
;; where 60 = 15 × 4 = (1 + 2 + 3 + 4 + 5) × 4.
|
||
'(initial-value 5 4 3 2 1 xyz 60)
|
||
(let* ((t1 (service-type (name 't1) (extensions '())
|
||
(compose concatenate)
|
||
(extend cons)))
|
||
(t2 (service-type (name 't2)
|
||
(extensions
|
||
(list (service-extension t1
|
||
(cut list 'xyz <>))))
|
||
(compose (cut reduce + 0 <>))
|
||
(extend *)))
|
||
(t3 (service-type (name 't3)
|
||
(extensions
|
||
(list (service-extension t2 identity)
|
||
(service-extension t1 list)))))
|
||
(r (fold-services (cons* (service t1 'initial-value)
|
||
(service t2 4)
|
||
(map (lambda (x)
|
||
(service t3 x))
|
||
(iota 5 1)))
|
||
#:target-type t1)))
|
||
(and (eq? (service-kind r) t1)
|
||
(service-parameters r))))
|
||
|
||
(test-assert "fold-services, ambiguity"
|
||
(let* ((t1 (service-type (name 't1) (extensions '())
|
||
(compose concatenate)
|
||
(extend cons)))
|
||
(t2 (service-type (name 't2)
|
||
(extensions
|
||
(list (service-extension t1 list)))))
|
||
(s (service t2 42)))
|
||
(guard (c ((ambiguous-target-service-error? c)
|
||
(and (eq? (ambiguous-target-service-error-target-type c)
|
||
t1)
|
||
(eq? (ambiguous-target-service-error-service c)
|
||
s))))
|
||
(fold-services (list (service t1 'first)
|
||
(service t1 'second)
|
||
s)
|
||
#:target-type t1)
|
||
#f)))
|
||
|
||
(test-assert "fold-services, missing target"
|
||
(let* ((t1 (service-type (name 't1) (extensions '())))
|
||
(t2 (service-type (name 't2)
|
||
(extensions
|
||
(list (service-extension t1 list)))))
|
||
(s (service t2 42)))
|
||
(guard (c ((missing-target-service-error? c)
|
||
(and (eq? (missing-target-service-error-target-type c)
|
||
t1)
|
||
(eq? (missing-target-service-error-service c)
|
||
s))))
|
||
(fold-services (list s) #:target-type t1)
|
||
#f)))
|
||
|
||
(test-assert "shepherd-service-back-edges"
|
||
(let* ((s1 (shepherd-service (provision '(s1)) (start #f)))
|
||
(s2 (shepherd-service (provision '(s2))
|
||
(requirement '(s1))
|
||
(start #f)))
|
||
(s3 (shepherd-service (provision '(s3))
|
||
(requirement '(s1 s2))
|
||
(start #f)))
|
||
(e (shepherd-service-back-edges (list s1 s2 s3))))
|
||
(and (lset= eq? (e s1) (list s2 s3))
|
||
(lset= eq? (e s2) (list s3))
|
||
(null? (e s3)))))
|
||
|
||
(test-end)
|
||
|
||
|
||
(exit (= (test-runner-fail-count (test-runner-current)) 0))
|